¿Cómo hacer Logout y cerrar el navegador web usando Robocorp?

¿Cómo hacer Logout y cerrar el navegador web usando Robocorp?

Para finalizar la automatización de nuestro robot, en la presente sesión aprenderemos cómo hacer el “Logout” de la sesión iniciada en la página web y como cerrar el navegador. Para esto, realizaremos el siguiente procedimiento:

1. Crear una nueva “Tasks” llamada “log out and close”.
2. Insertamos una nueva “Keyword” llamada de la misma manera, es decir, “log out and close” y asignamos sus funciones así:

• Inspeccionar las propiedades del botón de “Log out”.
• En una nueva línea seguido de un “TAB” indicamos la acción a realizar, escribiendo las palabras “click button” y cambiamos el “locator” por “logout”.
• En una línea adicional seguido de un “TAB” Escribimos el nombre de la acción, que será “Close Browser”.

3. Modificamos la “tasks” de la línea en la que se había indicado que se realizaría el “log out and close”, y antes de dicha frase, entre paréntesis “[“ “]” escribimos la palabra “teardown” + “TAB”.

4. Guardamos los cambios realizados con el comando “Ctrl” + “S” y corremos el robot con el comando “Ctrl” + “Shift” + “P”, seleccionando la opción “Robocorp: Run Robot”, para revisar que las actualizaciones realizadas en el código funcionen.

De esta manera y para finalizar la presente sesión, como resultado de la misma tu código será este:

*** Settings ***
Documentation     robot que hace un login.
Library    RPA.Browser.Selenium    auto_close=${FALSE}
Library    RPA.HTTP
Library    RPA.Excel.Files
Library    RPA.PDF
*** Keywords ***
Open intranet robocorp
    Open Available Browser    https://robotsparebinindustries.com/#/
Log in
    Input Text    username    maria
    Input Password    password    thoushallnotpass
    Submit Form
    Wait Until Page Contains Element    id:sales-form

Download the excel file
    Download    https://robotsparebinindustries.com/SalesData.xlsx

Fill and submit the form for one person
    [Arguments]    ${sales_rep}
    Input Text    firstname    ${sales_rep}[First Name]
    Input Text    lastname    ${sales_rep}[Last Name]
    Select From List By Value    salestarget     ${sales_rep}[Sales Target]   
    Input Text    salesresult    ${sales_rep}[Sales]
    Click Button    Submit
Fill the form using the data from the excel file
    Open Workbook    SalesData.xlsx
    ${sales_reps}=    Read Worksheet As Table    header=True
    Close Workbook
    FOR    ${sales_rep}    IN    @{sales_reps}
        Fill and submit the form for one person    ${sales_rep}        
    END
Collect the results
    Screenshot    css:div.sales-summary    ${OUTPUT_DIR}${/}sales_summary.png
Export the table as a PDF
    Wait Until Element Is Visible    id:sales-results
    ${sales_results_html}=    Get Element Attribute    id:sales-results    outerHTML
    Html To Pdf    ${sales_results_html}    ${OUTPUT_DIR}${/}sales_results.pdf
log out and close 
    Click Button    logout
    Close Browser
*** Tasks ***
Open Browser And Log In
    Open intranet robocorp
    Log in
    Download the excel file
    Fill the form using the data from the excel file
    Collect the results
    Export the table as a PDF
    [teardown]    log out and close