¿Cómo extraer la información para diligenciar un formulario en una página web con ayuda de Robocorp?

¿Cómo extraer la información para diligenciar un formulario en una página web con ayuda de Robocorp?

Para lograr esta tarea, es necesario emplear las herramientas con las que cuenta Robocorp, siendo en este caso en específico el uso de “Argumentos”, sin embargo, antes de aprender la manera en que debe hacerse, es necesario terminar con la automatización realizada durante la sesión anterior, con el fin de automatizar el botón de “Submit” dando “Click”, al momento de ejecutar el robot así:

1. Con ayuda de los conocimientos adquiridos previamente, inspeccionar las propiedades del botón “Submit” para lograr identificar cuál es su tipo y que nombre recibe.
2. Insertamos una nueva “Keyword”, seguida de un “TAB”, escribimos la palabra “Click” y dentro del listado elegimos la opción de “Submit Button” y en “locator”, colocamos “Submit”.

Cómo extraer la información del archivo de Excel?

1. Insertar una nueva librería en “Settings”, la cual se llamará “Library” + “TAB”, seguido de “RPA.Excel.Files”.
2. Borrar la “Task” que permitía “Fill and sbmit the form for one person”, ya que con la base de datos de excel se realizará para varias personas.
3. Crear una nueva “Keyword” llamada “Fill the form using the data from the excel file”. En esa misma “keyword” especificamos la manera en que se abrirá el Excel, para esto, en una nueva línea, seguida de un “TAB” escribimos la palabra “Open” y dentro del listado elegimos la nombrada como “Open Worbook”. Modificamos su “Path” con el nombre de del archivo guardado anteriormente en la ruta seleccionada, el cual es, “SalesData.xlsx”.

4. En una nueva línea del “Keyword” recién creado, introduciremos una variable. Para esto debes escribir el signo “$”, y entre corchetes escribimos “sales_reps” seguido de un signo “=” + “TAB” y escribimos “Read Worksheet As Table”, + “TAB”, seguido de la orden para que dentro de las columnas del Excel busque los encabezados, para esto debemos escribir “header=True”.
5. Teniendo en cuenta que anteriormente se abrió el “Worbook” es necesario cerrarlo, para esto, en una nueva línea seguido de un “TAB” escribimos la palabra “Close” y dentro del listado elegimos la nombrada como “close workbook”.
6. Creamos un ciclo en una nueva línea, iniciando con un “TAB” seguido de la palabra “FOR” y realizamos los cambios que se requieren en cada uno de sus componentes así: * Componente 1 FOR (element) ↔ “sales_rep”       * Componente 2 IN (LIST) ↔ “sales_reps”         * Componente 3 LOG (element) ↔ se suprime, ya que no se requiere.          *Componente 4. El cual está dentro del ciclo. Insertamos un “TAB” seguido de la primera acción a realizar la cual será “Fill and submit the form for one person” + “TAB” seguido del argumento ${sales_rep}.
7. Recibir el argumento dentro del “keyword” creado anteriormente y nombrado como “Fill and submit the form for one person”. Para esto, es necesario insertar una llave cuadrada “[“seguida de la palabra “Arguments” + “TAB” y el nombre del argumento insertado antes, que en este caso es ${sales_rep}.En ese mismo “Keyword” modificamos el nombre del “firstname” con el argumento, es decir, “${sales_rep}”, + una llave cuadrada “[“ junto a la especificación del lugar de donde se tomará la información, especificando el sitio de la misma en el archivo, es decir “First Name”.Repetimos el procedimiento para “lastname” reemplazando el apellido con el argumento, es decir, “${sales_rep}”, + una llave cuadrada “[“ junto a la especificación del lugar de donde se tomará la información, especificando el sitio de la misma en el archivo, es decir “Last Name”.De igual forma para el “salestarget” cambiamos la cantidad con “${sales_rep}”, + una llave cuadrada “[“ junto a nombre del encabezado de esa columna, es decir “Sales Target”.

   Así mismo, para el “salesresult” cambiamos la cantidad con “${sales_rep}”, + una llave cuadrada “[“ junto a nombre del encabezado de esa columna, es decir “Sales”.

8. Guardamos los cambios realizados con el comando “Ctrl” + “S” y corremos el robot con el comando “Ctrl” + “Shift” + “P”, seleccionando la opción “Robocorp: Run Robot”, para verificar que el flujo este funcionando de la manera esperada.

De esta manera y para finalizar la presente sesión, como resultado de la misma tu código será este:

*** Settings ***
Documentation     robot que hace un login.
Library    RPA.Browser.Selenium    auto_close=${FALSE}
Library    RPA.HTTP
Library    RPA.Excel.Files
*** Keywords ***
Open intranet robocorp
    Open Available Browser    https://robotsparebinindustries.com/#/
Log in
    Input Text    username    maria
    Input Password    password    thoushallnotpass
    Submit Form
    Wait Until Page Contains Element    id:sales-form

Download the excel file
    Download    https://robotsparebinindustries.com/SalesData.xlsx
Fill and submit the form for one person
    [Arguments]    ${sales_rep}
    Input Text    firstname    ${sales_rep}[First Name]
    Input Text    lastname    ${sales_rep}[Last Name]
    Select From List By Value    salestarget     ${sales_rep}[Sales Target]   
    Input Text    salesresult    ${sales_rep}[Sales]
    Click Button    Submit
Fill the form using the data from the excel file
    Open Workbook    SalesData.xlsx
    ${sales_reps}=    Read Worksheet As Table    header=True
    Close Workbook
    FOR    ${sales_rep}    IN    @{sales_reps}
        Fill and submit the form for one person    ${sales_rep}
    END
*** Tasks ***
Open Browser And Log In
    Open intranet robocorp
    Log in
    Download the excel file
    Fill the form using the data from the excel file